FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
PROJECT_SRC_DIR := "${THISDIR}/${PN}"

# The URI is required for the autobump script but keep it commented
# to not override the upstream value
# SRC_URI += "git://github.com/openbmc/phosphor-host-ipmid;branch=master;protocol=https"

SRC_URI += "file://phosphor-ipmi-host.service \
            file://0063-Save-the-pre-timeout-interrupt-in-dbus-property.patch \
            file://sensor-wait-sel.conf \
            file://0001-ipmi-cmd-support-set-sel-time-utc-offset.patch \
            file://0001-add-sensor-config-file.patch \
            file://0001-Fix-incorrect-thresholdLevelsStates-response-for-Get.patch \
            file://0001-Add-multiplierM-offsetB-bExp-rExp-items-in-sensor_da.patch \
            file://0001-Add-power-cycle-trigger-async-firmware-update.patch \
            "
FILES:${PN} += "${datadir}/ipmi-providers"

PACKAGECONFIG:remove = "allowlist"
PACKAGECONFIG:remove = "i2c-allowlist"
PACKAGECONFIG:remove = "boot-flag-safe-mode"
RDEPENDS:${PN}:remove = "clear-once"

# remove the softpoweroff service since we do not need it
SYSTEMD_SERVICE:${PN}:remove = " \
    xyz.openbmc_project.Ipmi.Internal.SoftPowerOff.service"

SYSTEMD_LINK:${PN}:remove = " \
    ../xyz.openbmc_project.Ipmi.Internal.SoftPowerOff.service:obmc-host-shutdown@0.target.requires/xyz.openbmc_project.Ipmi.Internal.SoftPowerOff.service \
    "

# remove dependencies from main recipe since we control it with local service file
unset IPMI_HOST_NEEDED_SERVICES

do_install:append(){
    rm -f ${D}/${bindir}/phosphor-softpoweroff

	install -d ${D}${systemd_unitdir}/system/phosphor-ipmi-host.service.d/
	install -m 0644 ${WORKDIR}/sensor-wait-sel.conf ${D}${systemd_unitdir}/system/phosphor-ipmi-host.service.d/
}