Initial commit
This commit is contained in:
Your Name
@@ -0,0 +1,35 @@
|
||||
From 3fc716357ce1372d9418dc86f24315b34d9808de Mon Sep 17 00:00:00 2001
|
||||
From: Ross Burton <ross.burton@arm.com>
|
||||
Date: Mon, 5 Dec 2022 17:02:32 +0000
|
||||
Subject: [PATCH] add yocto-specific install-ptest target
|
||||
|
||||
Add a target to install the test suite.
|
||||
|
||||
Upstream-Status: Inappropriate
|
||||
Signed-off-by: Ross Burton <ross.burton@arm.com>
|
||||
|
||||
---
|
||||
Makefile.am | 10 ++++++++++
|
||||
1 file changed, 10 insertions(+)
|
||||
|
||||
diff --git a/Makefile.am b/Makefile.am
|
||||
index 5bc4018..57d27af 100644
|
||||
--- a/Makefile.am
|
||||
+++ b/Makefile.am
|
||||
@@ -26,6 +26,16 @@ check_PROGRAMS = \
|
||||
testlimits \
|
||||
testrecurse
|
||||
|
||||
+ptestdir=$(libexecdir)
|
||||
+install-test-data: $(check_PROGRAMS)
|
||||
+ install -d $(DESTDIR)$(ptestdir) $(DESTDIR)$(ptestdir)/python/
|
||||
+ for T in $(check_PROGRAMS); do \
|
||||
+ $(LIBTOOL) --mode=install $(INSTALL_PROGRAM) $$T $(DESTDIR)$(ptestdir) ;\
|
||||
+ done
|
||||
+ cp -r $(srcdir)/test $(DESTDIR)$(ptestdir)
|
||||
+ cp -r $(srcdir)/result $(DESTDIR)$(ptestdir)
|
||||
+ cp -r $(srcdir)/python/tests $(DESTDIR)$(ptestdir)/python
|
||||
+
|
||||
bin_PROGRAMS = xmllint xmlcatalog
|
||||
|
||||
bin_SCRIPTS = xml2-config
|
||||
+20
@@ -0,0 +1,20 @@
|
||||
#!/bin/sh
|
||||
|
||||
set -e
|
||||
|
||||
export LC_ALL=en_US.UTF-8
|
||||
|
||||
# testModule isn't that useful and hard-codes buildtree, so we don't run that
|
||||
TESTS="runtest runsuite testrecurse testchar testdict testThreads runxmlconf testapi"
|
||||
|
||||
for T in $TESTS; do
|
||||
echo Running $T
|
||||
./$T && echo PASS: $T || echo FAIL: $T
|
||||
done
|
||||
|
||||
if test -d python/tests; then
|
||||
cd python/tests
|
||||
for T in *.py; do
|
||||
python3 ./$T && echo PASS: $T || echo FAIL: $T
|
||||
done
|
||||
fi
|
||||
@@ -0,0 +1,96 @@
|
||||
SUMMARY = "XML C Parser Library and Toolkit"
|
||||
DESCRIPTION = "The XML Parser Library allows for manipulation of XML files. Libxml2 exports Push and Pull type parser interfaces for both XML and HTML. It can do DTD validation at parse time, on a parsed document instance or with an arbitrary DTD. Libxml2 includes complete XPath, XPointer and Xinclude implementations. It also has a SAX like interface, which is designed to be compatible with Expat."
|
||||
HOMEPAGE = "https://gitlab.gnome.org/GNOME/libxml2"
|
||||
BUGTRACKER = "http://bugzilla.gnome.org/buglist.cgi?product=libxml2"
|
||||
SECTION = "libs"
|
||||
LICENSE = "MIT"
|
||||
LIC_FILES_CHKSUM = "file://Copyright;md5=2044417e2e5006b65a8b9067b683fcf1 \
|
||||
file://hash.c;beginline=6;endline=15;md5=e77f77b12cb69e203d8b4090a0eee879 \
|
||||
file://list.c;beginline=4;endline=13;md5=b9c25b021ccaf287e50060602d20f3a7 \
|
||||
file://trio.c;beginline=5;endline=14;md5=cd4f61e27f88c1d43df112966b1cd28f"
|
||||
|
||||
DEPENDS = "zlib virtual/libiconv"
|
||||
|
||||
inherit gnomebase
|
||||
|
||||
SRC_URI += "http://www.w3.org/XML/Test/xmlts20130923.tar;subdir=${BP};name=testtar \
|
||||
file://run-ptest \
|
||||
file://install-tests.patch \
|
||||
"
|
||||
|
||||
SRC_URI[archive.sha256sum] = "737e1d7f8ab3f139729ca13a2494fd17bf30ddb4b7a427cf336252cab57f57f7"
|
||||
SRC_URI[testtar.sha256sum] = "c6b2d42ee50b8b236e711a97d68e6c4b5c8d83e69a2be4722379f08702ea7273"
|
||||
|
||||
BINCONFIG = "${bindir}/xml2-config"
|
||||
|
||||
PACKAGECONFIG ??= "python \
|
||||
${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \
|
||||
"
|
||||
PACKAGECONFIG[python] = "--with-python=${PYTHON},--without-python,python3"
|
||||
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
|
||||
|
||||
inherit autotools pkgconfig binconfig-disabled ptest
|
||||
|
||||
inherit ${@bb.utils.contains('PACKAGECONFIG', 'python', 'python3targetconfig', '', d)}
|
||||
|
||||
LDFLAGS:append:riscv64 = "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld ptest', ' -fuse-ld=bfd', '', d)}"
|
||||
|
||||
RDEPENDS:${PN}-ptest += "bash make locale-base-en-us ${@bb.utils.contains('PACKAGECONFIG', 'python', 'libgcc python3-core python3-logging python3-shell python3-stringold python3-threading python3-unittest ${PN}-python', '', d)}"
|
||||
|
||||
RDEPENDS:${PN}-python += "${@bb.utils.contains('PACKAGECONFIG', 'python', 'python3-core', '', d)}"
|
||||
|
||||
RDEPENDS:${PN}-ptest:append:libc-musl = " musl-locales"
|
||||
RDEPENDS:${PN}-ptest:append:libc-glibc = " glibc-gconv-ebcdic-us \
|
||||
glibc-gconv-ibm1141 \
|
||||
glibc-gconv-iso8859-5 \
|
||||
glibc-gconv-euc-jp \
|
||||
"
|
||||
|
||||
# WARNING: zlib is required for RPM use
|
||||
EXTRA_OECONF = "--without-debug --without-legacy --with-catalog --with-c14n --without-lzma --with-fexceptions"
|
||||
EXTRA_OECONF:class-native = "--without-legacy --with-c14n --without-lzma --with-zlib"
|
||||
EXTRA_OECONF:class-nativesdk = "--without-legacy --with-c14n --without-lzma --with-zlib"
|
||||
EXTRA_OECONF:linuxstdbase = "--with-debug --with-legacy --with-c14n --without-lzma --with-zlib"
|
||||
|
||||
python populate_packages:prepend () {
|
||||
# autonamer would call this libxml2-2, but we don't want that
|
||||
if d.getVar('DEBIAN_NAMES'):
|
||||
d.setVar('PKG:libxml2', '${MLPREFIX}libxml2')
|
||||
}
|
||||
|
||||
PACKAGE_BEFORE_PN += "${PN}-utils"
|
||||
PACKAGES += "${PN}-python"
|
||||
|
||||
FILES:${PN}-staticdev += "${PYTHON_SITEPACKAGES_DIR}/*.a"
|
||||
FILES:${PN}-utils = "${bindir}/*"
|
||||
FILES:${PN}-python = "${PYTHON_SITEPACKAGES_DIR}"
|
||||
|
||||
do_configure:prepend () {
|
||||
# executables take longer to package: these should not be executable
|
||||
find ${S}/xmlconf/ -type f -exec chmod -x {} \+
|
||||
}
|
||||
|
||||
do_install_ptest () {
|
||||
oe_runmake DESTDIR=${D} ptestdir=${PTEST_PATH} install-test-data
|
||||
|
||||
cp -r ${S}/xmlconf ${D}${PTEST_PATH}
|
||||
|
||||
if ! ${@bb.utils.contains('PACKAGECONFIG', 'python', 'true', 'false', d)}; then
|
||||
rm -rf ${D}${PTEST_DIR}/python
|
||||
fi
|
||||
}
|
||||
|
||||
# with musl we need to enable icu support explicitly for these tests
|
||||
do_install_ptest:append:libc-musl () {
|
||||
rm -rf ${D}/${PTEST_PATH}/test/icu_parse_test.xml
|
||||
}
|
||||
|
||||
do_install:append:class-native () {
|
||||
# Docs are not needed in the native case
|
||||
rm ${D}${datadir}/gtk-doc -rf
|
||||
|
||||
create_wrapper ${D}${bindir}/xmllint 'XML_CATALOG_FILES=${XML_CATALOG_FILES:-${sysconfdir}/xml/catalog}'
|
||||
}
|
||||
do_install[vardepsexclude] += "XML_CATALOG_FILES:-${sysconfdir}/xml/catalog"
|
||||
|
||||
BBCLASSEXTEND = "native nativesdk"
|
||||
Reference in New Issue
Block a user