Initial commit

meta-raspberrypi/recipes-core/images/rpi-test-image.bb

@@ -0,0 +1,6 @@
+# Base this image on core-image-base
+include recipes-core/images/core-image-base.bb
+
+COMPATIBLE_MACHINE = "^rpi$"
+
+IMAGE_INSTALL:append = " packagegroup-rpi-test"

meta-raspberrypi/recipes-core/packagegroups/packagegroup-core-tools-testapps.bbappend

@@ -0,0 +1,2 @@
+# mesa-demos needs gles1 and userland driver does not have it, works ok with vc4 graphics driver
+X11GLTOOLS:remove:rpi = "${@bb.utils.contains('MACHINE_FEATURES', 'vc4graphics', '', 'mesa-demos', d)}"

meta-raspberrypi/recipes-core/packagegroups/packagegroup-rpi-test.bb

@@ -0,0 +1,33 @@
+DESCRIPTION = "RaspberryPi Test Packagegroup"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+COMPATIBLE_MACHINE = "^rpi$"
+
+OMXPLAYER  = "${@bb.utils.contains('MACHINE_FEATURES', 'vc4graphics', '', 'omxplayer', d)}"
+
+RDEPENDS:${PN} = "\
+    ${OMXPLAYER} \
+    bcm2835-tests \
+    raspi-gpio \
+    rpio \
+    rpi-gpio \
+    pi-blaster \
+    python3-adafruit-circuitpython-register \
+    python3-adafruit-platformdetect \
+    python3-adafruit-pureio \
+    python3-rtimu \
+    connman \
+    connman-client \
+    wireless-regdb-static \
+    bluez5 \
+"
+
+RRECOMMENDS:${PN} = "\
+    ${@bb.utils.contains("BBFILE_COLLECTIONS", "meta-multimedia", "bigbuckbunny-1080p bigbuckbunny-480p bigbuckbunny-720p", "", d)} \
+    ${MACHINE_EXTRA_RRECOMMENDS} \
+"

meta-raspberrypi/recipes-core/psplash/files/framebuf.conf

@@ -0,0 +1,4 @@
+[Unit]
+Requires=sys-devices-platform-gpu-graphics-fb0.device
+After=sys-devices-platform-gpu-graphics-fb0.device
+

meta-raspberrypi/recipes-core/psplash/psplash_%.bbappend

@@ -0,0 +1,12 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+SPLASH_IMAGES:rpi = "file://psplash-raspberrypi-img.h;outsuffix=raspberrypi"
+
+SRC_URI:append:rpi = " file://framebuf.conf"
+
+do_install:append:rpi() {
+    if [ "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}" ]; then
+        install -Dm 0644 ${WORKDIR}/framebuf.conf ${D}${systemd_system_unitdir}/psplash-start.service.d/framebuf.conf
+    fi
+}
+
+FILES:${PN}:append:rpi = " ${systemd_system_unitdir}/psplash-start.service.d"

meta-raspberrypi/recipes-core/udev/udev-rules-rpi.bb

@@ -0,0 +1,19 @@
+DESCRIPTION = "udev rules for Raspberry Pi Boards"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+SRC_URI = " \
+	git://github.com/RPi-Distro/raspberrypi-sys-mods;protocol=https;branch=master \
+	file://can.rules \
+	"
+SRCREV = "5ce3ef2b7f377c23fea440ca9df0e30f3f8447cf"
+
+S = "${WORKDIR}/git"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+do_install () {
+    install -d ${D}${sysconfdir}/udev/rules.d
+    install -m 0644 ${S}/etc.armhf/udev/rules.d/99-com.rules ${D}${sysconfdir}/udev/rules.d/
+    install -m 0644 ${WORKDIR}/can.rules ${D}${sysconfdir}/udev/rules.d/
+}

meta-raspberrypi/recipes-core/udev/udev-rules-rpi/can.rules

@@ -0,0 +1 @@
+SUBSYSTEM=="net", DEVPATH=="/devices/platform/soc/3f204000.spi/spi_master/spi0/spi0.0/net/can0", RUN+="/sbin/ip link set can0 up type can bitrate 500000"

meta-raspberrypi/recipes-core/udev/udev-rules-udisks-rpi/80-udisks-rpi.rules

@@ -0,0 +1,10 @@
+##############################################################################################################
+
+# Partitions which desktops should not display
+#
+
+# boot partition
+ENV{ID_FS_TYPE}=="vfat", ENV{ID_FS_LABEL}=="raspberrypi", \
+  ENV{UDISKS_PRESENTATION_HIDE}="1", ENV{UDISKS_IGNORE}="1"
+
+##############################################################################################################

meta-raspberrypi/recipes-core/udev/udev-rules-udisks-rpi_1.0.bb

@@ -0,0 +1,13 @@
+DESCRIPTION = "add udisk/udev rule to hide boot partition from udev"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+SRC_URI = "file://80-udisks-rpi.rules"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+do_install () {
+	install -d ${D}${base_libdir}/udev/rules.d
+	install -m 644 ${WORKDIR}/80-udisks-rpi.rules ${D}${base_libdir}/udev/rules.d
+}
+
+FILES:${PN} = "${base_libdir}/udev/rules.d"