Initial commit

meta-phosphor/recipes-x86/chassis/x86-power-control_git.bb

@@ -0,0 +1,43 @@
+SUMMARY = "Chassis Power Control service for Intel based platforms"
+DESCRIPTION = "Chassis Power Control service for Intel based platforms"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
+SRCREV = "cc037b89fbfdf1c33dbf4461d5670e5395e4b19c"
+PV = "1.0+git${SRCPV}"
+
+SRC_URI = "git://github.com/openbmc/x86-power-control.git;protocol=https;branch=master"
+
+S = "${WORKDIR}/git"
+
+inherit meson systemd pkgconfig
+inherit obmc-phosphor-dbus-service
+
+SYSTEMD_SERVICE:${PN} += "chassis-system-reset.service \
+                         chassis-system-reset.target"
+DEPENDS += " \
+    boost \
+    i2c-tools \
+    libgpiod \
+    nlohmann-json \
+    sdbusplus \
+    phosphor-logging \
+  "
+FILES:${PN}  += "${systemd_system_unitdir}/xyz.openbmc_project.Chassis.Control.Power@.service"
+
+pkg_postinst:${PN}:append() {
+    mkdir -p $D$systemd_system_unitdir/sysinit.target.wants
+    for i in ${OBMC_HOST_INSTANCES};
+    do
+        LINK="$D$systemd_system_unitdir/sysinit.target.wants/xyz.openbmc_project.Chassis.Control.Power@${i}.service"
+        TARGET="../xyz.openbmc_project.Chassis.Control.Power@.service"
+        ln -s $TARGET $LINK
+    done
+}
+
+pkg_prerm:${PN}:append() {
+    for i in ${OBMC_HOST_INSTANCES};
+    do
+        LINK="$D$systemd_system_unitdir/sysinit.target.requires/xyz.openbmc_project.Chassis.Control.Power@${i}.service"
+        rm $LINK
+    done
+}

meta-phosphor/recipes-x86/libpeci/libpeci_git.bb

@@ -0,0 +1,15 @@
+SUMMARY = "PECI Library"
+DESCRIPTION = "PECI Library"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=7becf906c8f8d03c237bad13bc3dac53"
+SRCREV = "5c2fb321f414019d0fb797c657523a2ee376d8dc"
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[dbus-raw-peci] = "-Draw-peci='enabled',-Draw-peci='disabled',boost sdbusplus"
+PV = "0.1+git${SRCPV}"
+
+SRC_URI = "git://github.com/openbmc/libpeci;branch=master;protocol=https"
+
+S = "${WORKDIR}/git"
+SYSTEMD_SERVICE:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'dbus-raw-peci', 'com.intel.peci.service', '', d)}"
+
+inherit meson pkgconfig systemd

meta-phosphor/recipes-x86/peci-pcie/peci-pcie_git.bb

@@ -0,0 +1,17 @@
+SUMMARY = "PECI PCIe"
+DESCRIPTION = "Gathers PCIe information using PECI \
+and provides it on D-Bus"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=7becf906c8f8d03c237bad13bc3dac53"
+DEPENDS = "boost sdbusplus libpeci"
+SRCREV = "8b18f526772c96c785a62e3a811eacf24d3b637f"
+PV = "0.1+git${SRCPV}"
+
+SRC_URI = "git://github.com/openbmc/peci-pcie;branch=master;protocol=https"
+
+S = "${WORKDIR}/git"
+SYSTEMD_SERVICE:${PN} += "xyz.openbmc_project.PCIe.service"
+
+inherit cmake pkgconfig systemd
+
+EXTRA_OECMAKE = "-DYOCTO=1"