Initial commit

meta-phosphor/recipes-support/boost/boost_%.bbappend

@@ -0,0 +1,16 @@
+PACKAGECONFIG:openbmc-phosphor:class-target = ""
+
+#This is largely to improve our build times by not building or installing
+#modules that OpenBMC does not use by our coding standard.  Another thing to
+#note is that for most targets, coroutine and context libraries are also added
+#with a BOOST_LIBS:append:<platform> for most targets.  Chrono/Thread should not
+#be relied directly, but are required dependencies of context and coroutine.
+#See the relevant portion of the openbmc coding standard with regards to boost
+#libraries
+#
+#https://github.com/openbmc/docs/blob/master/cpp-style-and-conventions.md#boost
+#
+BOOST_LIBS:openbmc-phosphor:class-target = "chrono thread context coroutine"
+
+BOOST_LIBS:openbmc-phosphor:class-target:append:df-etcd = " \
+             random system filesystem atomic date_time regex"

meta-phosphor/recipes-support/gnupg/gnupg_%.bbappend

@@ -0,0 +1,2 @@
+# Remove unneeded gnupg help files to save space
+EXTRA_OECONF:append:openbmc-phosphor = " --disable-doc"

meta-phosphor/recipes-support/libgpiod/libgpiod_%.bbappend

@@ -0,0 +1 @@
+PACKAGECONFIG += " cxx"

meta-phosphor/recipes-support/lm_sensors/lmsensors-config_1.0.bbappend

@@ -0,0 +1,4 @@
+# Prevent lmsensors from pulling in lighttpd as lighttpd
+# uses md4 and we disable openssl md4 support.
+
+RRECOMMENDS:${PN}-cgi:remove = "lighttpd lighttpd-module-cgi"

meta-phosphor/recipes-support/nghttp2/nghttp2_%.bbappend

@@ -0,0 +1,15 @@
+EXTRA_OECMAKE:prepend = " \
+    -DENABLE_LIB_ONLY=ON \
+    -DENABLE_STATIC_LIB=ON \
+    -DENABLE_SHARED_LIB=OFF \
+    -DCMAKE_INTERPROCEDURAL_OPTIMIZATION=ON \
+    -DENABLE_SHARED_LIB=OFF \
+    -DENABLE_HTTP3=OFF \
+    -DWITH_LIBXML2=OFF \
+    -DWITH_JEMALLOC=OFF \
+    -DWITH_MRUBY=OFF \
+    -DWITH_NEVERBLEED=OFF \
+    -DWITH_LIBBPF=OFF \
+    -DENABLE_ASIO_LIB=OFF \
+    -DENABLE_THREADS=OFF \
+"

meta-phosphor/recipes-support/nss-pam-ldapd/files/nslcd.init

@@ -0,0 +1,84 @@
+#!/bin/sh
+
+set -x
+
+NAME="nslcd"
+CONFIG="/etc/nslcd.conf"
+DAEMON="/usr/sbin/nslcd"
+DESC="LDAP connection daemon"
+STATEDIR="/var/run/$NAME"
+PIDFILE="$STATEDIR/$NAME.pid"
+
+start() 
+{
+    if [ -e $PIDFILE ]; then
+        PIDDIR=/proc/$(cat $PIDFILE)
+        if [ -d ${PIDDIR} ]; then
+            echo "$DESC already running."
+            exit 1
+        else
+            echo "Removing stale PID file $PIDFILE"
+            rm -f $PIDFILE
+        fi
+    fi
+
+    echo -n "Starting $DESC..."
+
+    start-stop-daemon --start --oknodo \
+        --pidfile $PIDFILE --startas $DAEMON
+
+    if [ $? -eq 0 ]; then
+        echo "done."
+    else
+        echo "failed."
+    fi
+}
+
+stop() 
+{
+    echo -n "Stopping $DESC..."
+    start-stop-daemon --stop --quiet --pidfile $PIDFILE \
+      --name $NAME
+    if [ $? -eq 0 ]; then
+        echo "done."
+    else
+        echo "failed."
+    fi
+    rm -f $PIDFILE
+}
+
+status()
+{
+    if [ -f $PIDFILE ]; then
+        if $DAEMON --check
+        then
+            echo "$DESC is running (pid `cat $PIDFILE`"
+        else
+            echo "$DESC stopped"
+        fi
+    else
+        echo "$DESC stopped"
+    fi
+}
+
+case "$1" in
+    start)
+        start
+        ;;
+    stop)
+        stop
+        ;;
+    restart|force-reload|reload)
+        stop
+        start
+        ;;
+    status)
+	status
+        ;;
+    *)
+        echo "Usage: $0 {start|stop|force-reload|restart|reload|status}"
+        exit 1
+        ;;
+esac
+
+exit 0

meta-phosphor/recipes-support/nss-pam-ldapd/files/nslcd.service

@@ -0,0 +1,10 @@
+[Unit]
+Description=LDAP daemon
+After=syslog.target network.target
+
+[Service]
+Type=forking
+ExecStart=/usr/sbin/nslcd
+
+[Install]
+WantedBy=multi-user.target

meta-phosphor/recipes-support/nss-pam-ldapd/nss-pam-ldapd_0.9.8.bb

@@ -0,0 +1,53 @@
+SUMMARY = "NSS and PAM module for using LDAP as a naming service"
+DESCRIPTION = "\
+ daemon for NSS and PAM lookups using LDAP \
+ This package provides a daemon for retrieving user accounts and similar \
+ system information from LDAP. It is used by the libnss-ldapd and \
+ libpam-ldapd packages but is not very useful by itself. \
+ "
+HOMEPAGE = "http://arthurdejong.org/nss-pam-ldapd/"
+SECTION = "base"
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+DEPENDS += "libpam openldap krb5"
+
+SRC_URI = "\
+        http://arthurdejong.org/nss-pam-ldapd/${BPN}-${PV}.tar.gz \
+        file://nslcd.init \
+        file://nslcd.service \
+        "
+SRC_URI[md5sum] = "8c99fdc54f4bf9aca8c5f53fdb1403ff"
+SRC_URI[sha256sum] = "ef7362e7f2003da8c7beb7bcc03c30494acf712625aaac8badc6e7eb16f3453f"
+
+SYSTEMD_SERVICE:${PN} = "nslcd.service"
+
+inherit autotools
+inherit update-rc.d systemd
+
+EXTRA_OECONF = "\
+        --disable-pynslcd \
+        --libdir=${base_libdir} \
+        --with-pam-seclib-dir=${base_libdir}/security \
+        "
+
+do_install:append() {
+        install -D -m 0755 ${WORKDIR}/nslcd.init ${D}${sysconfdir}/init.d/nslcd
+        sed -i -e 's/^uid nslcd/# uid nslcd/;' ${D}${sysconfdir}/nslcd.conf
+        sed -i -e 's/^gid nslcd/# gid nslcd/;' ${D}${sysconfdir}/nslcd.conf
+        sed -i -e 's/^base dc=example,dc=com/base ${LDAP_DN}/;' ${D}${sysconfdir}/nslcd.conf
+        install -d ${D}${systemd_system_unitdir}
+        install -m 0644 ${WORKDIR}/nslcd.service ${D}${systemd_system_unitdir}
+}
+
+RDEPENDS:${PN} += "nscd"
+
+FILES:${PN} += "${base_libdir}/security ${datadir}"
+FILES:${PN}-dbg += "${base_libdir}/security/.debug"
+
+CONFFILES:${PN} += "${sysconfdir}/nslcd.conf"
+
+INITSCRIPT_NAME = "nslcd"
+INITSCRIPT_PARAMS = "defaults"
+
+LDAP_DN ?= "dc=my-domain,dc=com"

meta-phosphor/recipes-support/nss-pam-ldapd_fix/nss-pam-ldapd_%.bbappend

@@ -0,0 +1,4 @@
+do_install:append() {
+        sed -i -e '$anss_initgroups_ignoreusers ALLLOCAL' ${D}${sysconfdir}/nslcd.conf
+        install -m 0644 ${D}${sysconfdir}/nslcd.conf ${D}${sysconfdir}/nslcd.conf.default
+}

meta-phosphor/recipes-support/openldap/openldap_%.bbappend

@@ -0,0 +1,2 @@
+PACKAGECONFIG = "openssl modules \
+                ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"

meta-phosphor/recipes-support/rng-tools/rng-tools/10-nice.conf

@@ -0,0 +1,6 @@
+[Service]
+# Make the priority of the random number generator seeding
+# process nearly the lowest on the system but allow
+# daemons to have lower priority if desired. This makes our
+# system much more responsive during boot.
+Nice=18

meta-phosphor/recipes-support/rng-tools/rng-tools_%.bbappend

@@ -0,0 +1,25 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
+PACKAGECONFIG:remove = "\
+        ${@bb.utils.contains('MACHINE_FEATURES', 'hw-rng', \
+                             'libjitterentropy', '', d)}\
+        "
+
+SRC_URI += "file://10-nice.conf"
+
+inherit systemd
+
+do_install:append() {
+    # When using systemd and using libjitterentropy, install a config
+    # which runs rngd at a 'nice' priority.  libjitterentropy uses a
+    # lot of CPU early on in the boot process and makes the whole boot
+    # go slower.
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+        if ${@bb.utils.contains('PACKAGECONFIG', 'libjitterentropy', 'true', 'false', d)}; then
+            install -d ${D}${systemd_system_unitdir}/rngd.service.d
+            install -m 644 ${WORKDIR}/10-nice.conf \
+                ${D}${systemd_system_unitdir}/rngd.service.d
+        fi
+    fi
+}
+
+FILES:${PN} += "${systemd_system_unitdir}/rngd.service.d"