Initial commit

meta-phosphor/recipes-phosphor/network/phosphor-network_git.bb

@@ -0,0 +1,40 @@
+SUMMARY = "Network DBUS object"
+DESCRIPTION = "Network DBUS object"
+HOMEPAGE = "http://github.com/openbmc/phosphor-networkd"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=fa818a259cbed7ce8bc2a22d35a464fc"
+DEPENDS += "systemd"
+DEPENDS += "sdbusplus ${PYTHON_PN}-sdbus++-native"
+DEPENDS += "sdeventplus"
+DEPENDS += "phosphor-dbus-interfaces"
+DEPENDS += "phosphor-logging"
+DEPENDS += "libnl"
+DEPENDS += "stdplus"
+SRCREV = "05cbc5b7876a9fb0fd86c6d3b11c46da53d9a9ec"
+PACKAGECONFIG ??= "uboot-env default-link-local-autoconf default-ipv6-accept-ra persist-mac"
+PACKAGECONFIG[uboot-env] = "-Duboot-env=true,-Duboot-env=false,,${UBOOT_ENV_RDEPENDS}"
+PACKAGECONFIG[default-link-local-autoconf] = "-Ddefault-link-local-autoconf=true,-Ddefault-link-local-autoconf=false,,"
+PACKAGECONFIG[default-ipv6-accept-ra] = "-Ddefault-ipv6-accept-ra=true,-Ddefault-ipv6-accept-ra=false,,"
+PACKAGECONFIG[sync-mac] = "-Dsync-mac=true,-Dsync-mac=false,nlohmann-json,"
+PACKAGECONFIG[hyp-nw-config] = "-Dhyp-nw-config=true, -Dhyp-nw-config=false,,"
+PACKAGECONFIG[persist-mac] = "-Dpersist-mac=true, -persist-mac=false,,"
+PV = "1.0+git${SRCPV}"
+PR = "r1"
+
+SRC_URI = "git://github.com/openbmc/phosphor-networkd;branch=master;protocol=https"
+
+S = "${WORKDIR}/git"
+SYSTEMD_PACKAGES = "${PN}"
+SYSTEMD_SERVICE:${PN} += "xyz.openbmc_project.Network.service"
+SYSTEMD_SERVICE:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'hyp-nw-config', 'xyz.openbmc_project.Network.Hypervisor.service', '', d)}"
+
+inherit meson pkgconfig
+inherit python3native
+inherit systemd
+
+EXTRA_OEMESON:append = " -Dtests=disabled"
+
+FILES:${PN} += "${datadir}/dbus-1/system.d"
+FILES:${PN} += "${systemd_unitdir}/network/60-phosphor-networkd-default.network"
+
+UBOOT_ENV_RDEPENDS = "${@d.getVar('PREFERRED_PROVIDER_u-boot-fw-utils', True) or 'u-boot-fw-utils'}"

meta-phosphor/recipes-phosphor/network/phosphor-snmp/xyz.openbmc_project.Network.SNMP.service

@@ -0,0 +1,12 @@
+[Unit]
+Description=Phosphor SNMP conf Manager
+
+[Service]
+ExecStart=/usr/bin/env phosphor-network-snmpconf
+SyslogIdentifier=phosphor-network-snmpconf
+Restart=always
+Type=dbus
+BusName=xyz.openbmc_project.Network.SNMP
+
+[Install]
+WantedBy=multi-user.target

meta-phosphor/recipes-phosphor/network/phosphor-snmp_git.bb

@@ -0,0 +1,27 @@
+SUMMARY = "SNMP Manager Configuration"
+DESCRIPTION = "SNMP Manager Configuration."
+HOMEPAGE = "http://github.com/openbmc/phosphor-snmp"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
+DEPENDS += "systemd"
+DEPENDS += "sdbusplus ${PYTHON_PN}-sdbus++-native"
+DEPENDS += "phosphor-dbus-interfaces"
+DEPENDS += "phosphor-logging"
+DEPENDS += "net-snmp"
+SRCREV = "47652f2f20b3d69a2f1c26fb06e80e2f1c4f24d6"
+PV = "0.1+git${SRCPV}"
+PR = "r1"
+
+SRC_URI = "git://github.com/openbmc/phosphor-snmp;branch=master;protocol=https"
+
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig
+inherit python3native
+inherit obmc-phosphor-dbus-service
+
+EXTRA_OEMESON = " \
+    -Dtests=disabled \
+    "
+
+DBUS_SERVICE:${PN} += "xyz.openbmc_project.Network.SNMP.service"