Initial commit

meta-phosphor/recipes-phosphor/inventory/phosphor-inventory-manager-assettag.bb

@@ -0,0 +1,18 @@
+SUMMARY = "Recipe to create AssetTag property in inventory manager"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+PROVIDES += "virtual/phosphor-inventory-manager-assettag"
+PR = "r1"
+
+SRC_URI = "file://assettag.yaml"
+
+S = "${WORKDIR}"
+
+inherit allarch
+inherit phosphor-inventory-manager
+
+do_install() {
+        install -D assettag.yaml ${D}${base_datadir}/events.d/assettag.yaml
+}
+
+FILES:${PN} += "${base_datadir}/events.d/assettag.yaml"

meta-phosphor/recipes-phosphor/inventory/phosphor-inventory-manager-assettag/assettag.yaml

@@ -0,0 +1,14 @@
+events:
+    - name: Creating AssetTag at startup
+      description: >
+          Create /system at startup and populate the AssetTag property with
+          empty string.
+      type: startup
+      actions:
+          - name: createObjects
+            objs:
+             /system:
+                xyz.openbmc_project.Inventory.Decorator.AssetTag:
+                  AssetTag:
+                    value: ""
+                    type: string

meta-phosphor/recipes-phosphor/inventory/phosphor-inventory-manager.inc

@@ -0,0 +1,5 @@
+HOMEPAGE = "http://github.com/openbmc/phosphor-inventory-manager"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
+SRC_URI = "git://github.com/openbmc/phosphor-inventory-manager;branch=master;protocol=https"
+SRCREV = "c3eb3879fec881ff26ca167dce33897c702b3b7e"

meta-phosphor/recipes-phosphor/inventory/phosphor-inventory-manager/xyz.openbmc_project.Inventory.Manager.service

@@ -0,0 +1,12 @@
+[Unit]
+Description=Phosphor Inventory Manager
+Before=mapper-wait@-xyz-openbmc_project-inventory.service
+
+[Service]
+Restart=always
+Type=dbus
+ExecStart=/usr/bin/phosphor-inventory
+BusName={BUSNAME}
+
+[Install]
+WantedBy=multi-user.target

meta-phosphor/recipes-phosphor/inventory/phosphor-inventory-manager_git.bb

@@ -0,0 +1,41 @@
+SUMMARY = "Phosphor Inventory Manager"
+DESCRIPTION = "Phosphor Inventory Manager is an inventory object \
+lifecycle management application, suitable for use on a wide variety \
+of OpenBMC platforms."
+DEPENDS += " \
+        phosphor-inventory-manager-assettag \
+        phosphor-dbus-interfaces \
+        phosphor-logging \
+        sdbusplus \
+        ${PYTHON_PN}-sdbus++-native \
+        libcereal \
+        ${PYTHON_PN}-native \
+        ${PYTHON_PN}-pyyaml-native \
+        ${PYTHON_PN}-mako-native \
+        nlohmann-json \
+        "
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[associations] = "-Dassociations=enabled, -Dassociations=disabled"
+PV = "1.0+git${SRCPV}"
+PR = "r1"
+
+S = "${WORKDIR}/git"
+
+inherit meson \
+        pkgconfig \
+        python3native \
+        phosphor-dbus-yaml \
+        phosphor-inventory-manager \
+        obmc-phosphor-dbus-service
+
+EXTRA_OEMESON = " \
+        -Dtests=disabled \
+        -DYAML_PATH=${STAGING_DIR_HOST}${base_datadir} \
+        -DIFACES_PATH=${STAGING_DIR_TARGET}${yaml_dir} \
+        "
+
+require phosphor-inventory-manager.inc
+
+OBMC_INVENTORY_PATH = "${OBMC_DBUS_PATH_ROOT}/inventory"
+OBMC_INVENTORY_MGR_IFACE = "${OBMC_DBUS_IFACE_ROOT}.Inventory.Manager"
+DBUS_SERVICE:${PN} = "${OBMC_INVENTORY_MGR_IFACE}.service"