Initial commit

meta-phosphor/recipes-phosphor/dbus/dbus-perms.bb

@@ -0,0 +1,19 @@
+SUMMARY = "Phosphor OpenBMC DBUS Permissions"
+DESCRIPTION = "Phosphor OpenBMC DBUS Permissions."
+HOMEPAGE = "http://github.com/openbmc/"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+PR = "r1"
+
+SRC_URI += "file://org.openbmc.conf"
+
+inherit allarch
+inherit dbus-dir
+
+do_install:append() {
+        install -d ${D}${dbus_system_confdir}
+        install -m 0644 ${WORKDIR}/org.openbmc.conf \
+                ${D}${dbus_system_confdir}
+}
+
+FILES:${PN}:append = " ${dbus_system_confdir}"

meta-phosphor/recipes-phosphor/dbus/dbus-perms/org.openbmc.conf

@@ -0,0 +1,8 @@
+<!DOCTYPE busconfig PUBLIC "-//freedesktop//DTD D-BUS Bus Configuration 1.0//EN"
+ "http://www.freedesktop.org/standards/dbus/1.0/busconfig.dtd">
+<busconfig>
+  <policy context="default">
+    <allow own="*"/>
+    <allow send_destination="*"/>
+  </policy>
+</busconfig>

meta-phosphor/recipes-phosphor/dbus/phosphor-dbus-interfaces_git.bb

@@ -0,0 +1,42 @@
+SUMMARY = "Phosphor DBus Interfaces"
+DESCRIPTION = "Generated bindings, using sdbus++, for the phosphor YAML"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
+DEPENDS += " \
+        ${PYTHON_PN}-sdbus++-native \
+        sdbusplus \
+        systemd \
+        "
+SRCREV = "402dc6a5beee58ee1e6514a425c542a0d879954c"
+PV = "1.0+git${SRCPV}"
+PR = "r1"
+
+SRC_URI = "git://github.com/openbmc/phosphor-dbus-interfaces;branch=master;protocol=https"
+
+S = "${WORKDIR}/git"
+
+inherit pkgconfig meson
+inherit obmc-phosphor-utils
+inherit phosphor-dbus-yaml
+inherit python3native
+
+# Markdown files are installed into /usr/share/phosphor-dbus-interfaces so
+# add them to the 'doc' subpackage.
+FILES:${PN}-doc += "${datadir}/${BPN}"
+
+# Process OBMC_ORG_YAML_SUBDIRS to create Meson config options.
+# ex. xyz/openbmc_project -> -Ddata_xyz_openbmc_project=true
+def pdi_meson_config(d):
+    return ' '.join([
+        '-Ddata_' + x.replace('/', '_') + '=true' \
+                for x in listvar_to_list(d, 'OBMC_ORG_YAML_SUBDIRS')
+        ])
+pdi_meson_config[vardeps] = "OBMC_ORG_YAML_SUBDIRS"
+EXTRA_OEMESON += "${@pdi_meson_config(d)}"
+# Remove all schemas by default regardless of the meson_options.txt config
+do_write_config:append() {
+    for intf in $(grep "^option('data_" ${S}/meson_options.txt | sed "s,^.*\(data_[^']*\).*$,\1,"); do
+        sed -i "/^\[built-in options\]\$/a$intf = false" ${WORKDIR}/meson.cross
+    done
+}
+do_write_config[deptask] += "do_unpack"

meta-phosphor/recipes-phosphor/dbus/phosphor-dbus-monitor-config.bb

@@ -0,0 +1,20 @@
+# To add additional config files, create a recipe in your layer,
+# and add it to PHOSPHOR_DBUS_MONITOR_CONFIGS with a bbappend to this recipe.
+SUMMARY = "Phosphor DBus Monitor Configuration"
+DESCRIPTION = "Meta-recipe, pulling in non-native recipes that wish to add \
+configuration files to the /usr/share/phosphor-dbus-monitor filesystem."
+HOMEPAGE = "http://github.com/openbmc/phosphor-dbus-monitor"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
+DEPENDS += "${PHOSPHOR_DBUS_MONITOR_CONFIGS}"
+PR = "r1"
+
+inherit phosphor-dbus-monitor
+
+do_install() {
+    mkdir -p ${D}${config_dir}
+}
+
+FILES:${PN} += "${config_dir}"
+
+PHOSPHOR_DBUS_MONITOR_CONFIGS ??= ""

meta-phosphor/recipes-phosphor/dbus/phosphor-dbus-monitor/phosphor-dbus-monitor.service

@@ -0,0 +1,10 @@
+[Unit]
+Description=Phosphor DBus Monitor
+
+[Service]
+Restart=always
+ExecStart=/usr/bin/env phosphor-dbus-monitor
+SyslogIdentifier=phosphor-dbus-monitor
+
+[Install]
+WantedBy=multi-user.target

meta-phosphor/recipes-phosphor/dbus/phosphor-dbus-monitor/phosphor-msl-verify.service

@@ -0,0 +1,10 @@
+[Unit]
+Description=Phosphor MSL Verification
+After=mapper-wait@-xyz-openbmc_project-inventory.service
+Wants=mapper-wait@-xyz-openbmc_project-inventory.service
+
+[Service]
+Type=oneshot
+RemainAfterExit=yes
+ExecStart=/usr/bin/env phosphor-msl-verify
+SyslogIdentifier=phosphor-msl-verify

meta-phosphor/recipes-phosphor/dbus/phosphor-dbus-monitor_git.bb

@@ -0,0 +1,41 @@
+SUMMARY = "Phosphor DBus Monitor"
+DESCRIPTION = "Phosphor DBus Monitor is a general purpose DBus application \
+that watches DBus traffic for events and takes actions based on those events."
+HOMEPAGE = "http://github.com/openbmc/phosphor-dbus-monitor"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
+DEPENDS += " \
+        ${PN}-config \
+        phosphor-logging \
+        ${PYTHON_PN}-sdbus++-native \
+        sdeventplus \
+        gtest \
+        phosphor-snmp \
+        ${PYTHON_PN}-native \
+        ${PYTHON_PN}-pyyaml-native \
+        ${PYTHON_PN}-setuptools-native \
+        ${PYTHON_PN}-mako-native \
+        "
+SRCREV = "5875d5630998ace8472c5fe5b5d7e1bcecd4f287"
+PV = "1.0+git${SRCPV}"
+PR = "r1"
+
+SRC_URI = "git://github.com/openbmc/phosphor-dbus-monitor;branch=master;protocol=https"
+
+SYSTEMD_PACKAGES = "${PN} phosphor-msl-verify"
+SYSTEMD_SERVICE:phosphor-msl-verify = "phosphor-msl-verify.service"
+S = "${WORKDIR}/git"
+
+inherit meson \
+        pkgconfig \
+        python3native \
+        phosphor-dbus-monitor \
+        obmc-phosphor-systemd
+
+EXTRA_OEMESON = " \
+        -DYAML_PATH=${STAGING_DIR_HOST}${config_dir} \
+        "
+
+FILES:phosphor-msl-verify = "${bindir}/phosphor-msl-verify"
+
+PACKAGE_BEFORE_PN = "phosphor-msl-verify"

meta-phosphor/recipes-phosphor/dbus/phosphor-objmgr_git.bb

@@ -0,0 +1,35 @@
+SUMMARY = "Phosphor DBUS Object Manager"
+DESCRIPTION = "Phosphor DBUS object manager."
+HOMEPAGE = "http://github.com/openbmc/phosphor-objmgr"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=fa818a259cbed7ce8bc2a22d35a464fc"
+DEPENDS += "systemd"
+DEPENDS += "boost"
+DEPENDS += "libtinyxml2"
+DEPENDS += "sdbusplus"
+DEPENDS += "phosphor-logging"
+DEPENDS += "cli11"
+SRCREV = "26ed98050e64e76892be5d5c2416b8a0044e3d9d"
+PV = "1.0+git${SRCPV}"
+PR = "r1"
+
+SRC_URI = "git://github.com/openbmc/phosphor-objmgr;branch=master;protocol=https"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[unit-failure-monitor] = "-Dunit-failure-monitor=enabled,-Dunit-failure-monitor=disabled,,"
+
+SYSTEMD_SERVICE:${PN} += " \
+        mapper-wait@.service \
+        mapper-subtree-remove@.service \
+        xyz.openbmc_project.ObjectMapper.service \
+        "
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig systemd
+
+EXTRA_OEMESON += "-Dtests=disabled"
+
+PROVIDES += "libmapper"
+PACKAGE_BEFORE_PN += "libmapper"
+FILES:libmapper = "${libdir}/lib*.so*"
+FILES:${PN} += "${datadir}/dbus-1"