Initial commit

meta-phosphor/recipes-phosphor/configuration/entity-manager/blocklist.json

@@ -0,0 +1,3 @@
+{
+    "buses": []
+}

meta-phosphor/recipes-phosphor/configuration/entity-manager/ibm-power10-cpu/blocklist.json

@@ -0,0 +1,3 @@
+{
+    "buses": [100, 101, 110, 111, 112, 113, 114, 115, 202, 203, 210, 211, 214, 215, 216, 217, 300, 301, 310, 311, 312, 313, 314, 315, 402, 403, 410, 411, 414, 415, 416, 417]
+}

meta-phosphor/recipes-phosphor/configuration/entity-manager/ibm-power9-cpu/blocklist.json

@@ -0,0 +1,3 @@
+{
+    "buses": [100, 101, 102, 103, 104, 105, 106, 107, 108, 109, 110, 111, 112, 113, 114, 200, 201, 202, 203, 204, 205, 206, 207, 208, 209, 210, 211, 212, 213, 214]
+}

meta-phosphor/recipes-phosphor/configuration/entity-manager_git.bb

@@ -0,0 +1,44 @@
+SUMMARY = "Entity Manager"
+DESCRIPTION = "Entity Manager provides d-bus configuration data \
+and configures system sensors"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=a6a4edad4aed50f39a66d098d74b265b"
+DEPENDS = "boost \
+           dbus \
+           nlohmann-json \
+           sdbusplus \
+           valijson \
+           ${PYTHON_PN}-jsonschema-native \
+"
+SRCREV = "4c94ed9f9ae0c3e81582154aff0b40d1d223a448"
+PACKAGECONFIG ??= "ipmi-fru"
+PACKAGECONFIG[ipmi-fru] = "-Dfru-device=true, -Dfru-device=false, i2c-tools,"
+PV = "0.1+git${SRCPV}"
+
+SRC_URI = "git://github.com/openbmc/entity-manager.git;branch=master;protocol=https \
+           file://blocklist.json \
+          "
+
+S = "${WORKDIR}/git"
+SYSTEMD_PACKAGES = "${PN} ${EXTRA_ENTITY_MANAGER_PACKAGES}"
+SYSTEMD_SERVICE:${PN} = "xyz.openbmc_project.EntityManager.service"
+SYSTEMD_SERVICE:fru-device = "xyz.openbmc_project.FruDevice.service"
+SYSTEMD_AUTO_ENABLE:fru-device:ibm-power-cpu = "disable"
+
+inherit pkgconfig meson systemd python3native
+
+EXTRA_OEMESON = "-Dtests=disabled"
+EXTRA_ENTITY_MANAGER_PACKAGES = " \
+    ${@bb.utils.contains('PACKAGECONFIG', 'ipmi-fru', 'fru-device', '', d)} \
+    "
+
+do_install:append() {
+    install -D ${WORKDIR}/blocklist.json ${D}${datadir}/${BPN}/blacklist.json
+}
+
+FILES:${PN} += " \
+    ${datadir}/dbus-1/system-services/xyz.openbmc_project.EntityManager.service \
+    "
+FILES:fru-device = "${bindir}/fru-device ${datadir}/${BPN}/blacklist.json"
+
+PACKAGE_BEFORE_PN = "${EXTRA_ENTITY_MANAGER_PACKAGES}"