Initial commit

meta-luxshare/meta-common/recipes-luxshare/ipmi-lux-oem/ipmi-oem/meson.build

@@ -0,0 +1,65 @@
+project(
+  'ipmi-oem',
+  'cpp',
+  version: '0.1',
+  meson_version: '>=1.1.1',
+  default_options: [
+    'werror=true',
+    'warning_level=3',
+    'cpp_std=c++23',
+  ])
+
+root = meson.current_source_dir()
+root_inc = include_directories('.')
+cpp = meson.get_compiler('cpp')
+
+# i2c-tools doesn't ship a pkg-config file for libi2c
+i2c = cpp.find_library('i2c')
+
+add_project_arguments(
+  cpp.get_supported_arguments([
+    '-DBOOST_ERROR_CODE_HEADER_ONLY',
+    '-DBOOST_SYSTEM_NO_DEPRECATED',
+    '-DBOOST_COROUTINES_NO_DEPRECATION_WARNING',
+    '-DBOOST_ASIO_DISABLE_THREADS',
+    '-DBOOST_ALL_NO_LIB',
+  ]),
+  language : 'cpp')
+
+add_project_arguments(
+  cpp.get_supported_arguments([
+    '-Wno-psabi',
+    '-Wno-missing-field-initializers',
+    '-Wno-pedantic',
+    '-Wno-non-virtual-dtor'
+  ]),
+  language: 'cpp')
+
+phosphor_logging_dep = dependency('phosphor-logging')
+phosphor_dbus_interfaces_dep = dependency('phosphor-dbus-interfaces')
+systemd = dependency('systemd')
+boost_coroutine = cpp.find_library('boost_coroutine', required: true)
+sdbusplus_dep = dependency('sdbusplus')
+ipmid_dep = dependency('libipmid')
+libs = declare_dependency(
+  include_directories: root_inc,
+  dependencies: [
+    phosphor_dbus_interfaces_dep,
+    phosphor_logging_dep,
+    sdbusplus_dep,
+    ipmid_dep,
+    systemd,
+    i2c
+  ])
+
+ipmi_oem_lib = library(
+  'ipmioem',
+  'ipmi-oem.cpp',
+  implicit_include_directories: false,
+  dependencies: libs,
+  version: meson.project_version(),
+  override_options: ['b_lundef=false'],
+  install: true,
+  install_dir: get_option('libdir') / 'ipmid-providers')
+
+