Initial commit

meta-intel-openbmc/meta-common/recipes-intel/ipmi/intel-ipmi-oem_git.bb

@@ -0,0 +1,32 @@
+SUMMARY = "Intel OEM IPMI commands"
+DESCRIPTION = "Intel OEM IPMI commands"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=a6a4edad4aed50f39a66d098d74b265b"
+
+SRC_URI = "git://github.com/openbmc/intel-ipmi-oem;branch=master;protocol=https"
+SRCREV = "84c203d2b74680e9dd60d1c48a2f6ca8f58462bf"
+
+S = "${WORKDIR}/git"
+PV = "0.1+git${SRCPV}"
+
+DEPENDS = "boost phosphor-ipmi-host phosphor-logging systemd phosphor-dbus-interfaces libgpiod libtinyxml2"
+
+inherit cmake obmc-phosphor-ipmiprovider-symlink pkgconfig
+
+EXTRA_OECMAKE="-DENABLE_TEST=0 -DYOCTO=1"
+
+LIBRARY_NAMES = "libzinteloemcmds.so"
+
+HOSTIPMI_PROVIDER_LIBRARY += "${LIBRARY_NAMES}"
+NETIPMI_PROVIDER_LIBRARY += "${LIBRARY_NAMES}"
+
+FILES:${PN}:append = " ${libdir}/ipmid-providers/lib*${SOLIBS}"
+FILES:${PN}:append = " ${libdir}/host-ipmid/lib*${SOLIBS}"
+FILES:${PN}:append = " ${libdir}/net-ipmid/lib*${SOLIBS}"
+FILES:${PN}-dev:append = " ${libdir}/ipmid-providers/lib*${SOLIBSDEV}"
+
+do_install:append(){
+   install -d ${D}${includedir}/intel-ipmi-oem
+   install -m 0644 -D ${S}/include/*.hpp ${D}${includedir}/intel-ipmi-oem
+}

meta-intel-openbmc/meta-common/recipes-intel/packagegroups/packagegroup-intel-apps.bb

@@ -0,0 +1,46 @@
+SUMMARY = "OpenBMC for Intel - Applications"
+PR = "r1"
+
+inherit packagegroup
+
+PROVIDES = "${PACKAGES}"
+PACKAGES = " \
+        ${PN}-chassis \
+        ${PN}-fans \
+        ${PN}-flash \
+        ${PN}-system \
+        "
+
+PROVIDES += "virtual/obmc-chassis-mgmt"
+PROVIDES += "virtual/obmc-fan-mgmt"
+PROVIDES += "virtual/obmc-flash-mgmt"
+PROVIDES += "virtual/obmc-system-mgmt"
+
+RPROVIDES:${PN}-chassis += "virtual-obmc-chassis-mgmt"
+RPROVIDES:${PN}-fans += "virtual-obmc-fan-mgmt"
+RPROVIDES:${PN}-flash += "virtual-obmc-flash-mgmt"
+RPROVIDES:${PN}-system += "virtual-obmc-system-mgmt"
+
+SUMMARY:${PN}-chassis = "Intel Chassis"
+RDEPENDS:${PN}-chassis = " \
+        x86-power-control \
+        obmc-host-failure-reboots \
+        "
+
+SUMMARY:${PN}-fans = "Intel Fans"
+RDEPENDS:${PN}-fans = " \
+        phosphor-pid-control \
+        "
+
+SUMMARY:${PN}-flash = "Intel Flash"
+RDEPENDS:${PN}-flash = " \
+        "
+
+SUMMARY:${PN}-system = "Intel System"
+RDEPENDS:${PN}-system = " \
+        bmcweb \
+        entity-manager \
+        intel-ipmi-oem \
+        dbus-sensors \
+        webui-vue \
+        "

meta-intel-openbmc/meta-common/recipes-intel/pfr/pfr-manager_git.bb

@@ -0,0 +1,23 @@
+SUMMARY = "PFR Manager Service"
+DESCRIPTION = "Daemon to handle all PFR functionalities"
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=7becf906c8f8d03c237bad13bc3dac53"
+inherit cmake systemd
+
+SRC_URI = "git://github.com/openbmc/pfr-manager;branch=master;protocol=https"
+
+PV = "0.1+git${SRCPV}"
+SRCREV = "1218aa64d109facdd2633f1205e5e4f1be6d8891"
+
+S = "${WORKDIR}/git"
+
+SYSTEMD_SERVICE:${PN} = "xyz.openbmc_project.PFR.Manager.service"
+
+DEPENDS += " \
+    sdbusplus \
+    phosphor-logging \
+    boost \
+    i2c-tools \
+    libgpiod \
+    "