Initial commit

meta-ibm/recipes-phosphor/logging/ibm-logging/com.ibm.Logging.service

@@ -0,0 +1,13 @@
+[Unit]
+Description=IBM Log Manager
+After=xyz.openbmc_project.Logging.service
+BindsTo=xyz.openbmc_project.Logging.service
+
+[Service]
+ExecStart=/usr/bin/ibm-log-manager
+Restart=always
+Type=dbus
+BusName={BUSNAME}
+
+[Install]
+WantedBy=xyz.openbmc_project.Logging.service

meta-ibm/recipes-phosphor/logging/ibm-logging/policyTable.json

@@ -0,0 +1,5 @@
+{
+    "_comment": "This file should be overridden with one from the machine layer.",
+    "events": {
+    }
+}

meta-ibm/recipes-phosphor/logging/ibm-logging_git.bb

@@ -0,0 +1,67 @@
+SUMMARY = "IBM enhanced error logging"
+DESCRIPTION = "Adds additional error logging functionality for IBM systems"
+PR = "r1"
+PV = "1.0+git${SRCPV}"
+HOMEPAGE = "https://github.com/openbmc/ibm-logging"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
+SRC_URI = "git://github.com/openbmc/ibm-logging;branch=master;protocol=https"
+SRCREV = "6a2b8956487404dd2f7e4aa06055c24a2b7271e1"
+
+inherit autotools
+inherit pkgconfig
+inherit python3native
+inherit obmc-phosphor-dbus-service
+inherit obmc-phosphor-systemd
+inherit phosphor-dbus-yaml
+
+DEPENDS += " \
+         ${PYTHON_PN}-pyyaml-native \
+         autoconf-archive-native \
+         phosphor-dbus-interfaces \
+         nlohmann-json \
+         phosphor-logging \
+         sdbusplus \
+         "
+
+S = "${WORKDIR}/git"
+
+SRC_URI += "file://policyTable.json"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[policy-interface] = "--enable-policy-interface, --disable-policy-interface,,"
+
+PACKAGECONFIG:ibm-ac-server = "policy-interface"
+
+SERVICE = "com.ibm.Logging.service"
+DBUS_SERVICE:${PN} += "${SERVICE}"
+
+#The link is so that this service will restart if phosphor-logging restarts.
+#The BindsTo in the service will not do the restart, it will only do the
+#original start and a stop.
+LOG_FMT = "../${SERVICE}:xyz.openbmc_project.Logging.service.wants/${SERVICE}"
+SYSTEMD_LINK:${PN} += "${LOG_FMT}"
+
+do_install:append(){
+
+    install -d ${D}${datadir}/ibm-logging
+
+    ${S}/condense_policy.py \
+        -p ${WORKDIR}/policyTable.json \
+        -c ${D}/${datadir}/ibm-logging/policy.json
+}
+
+#An optional task to generate a report on all of the errors
+#created by OpenBMC, and compare these errors to what is
+#in the error policy table
+do_report(){
+
+    ${S}/create_error_reports.py \
+        -p ${D}/${datadir}/ibm-logging/policy.json \
+        -y ${STAGING_DIR_TARGET}${yaml_dir} \
+        -e ${WORKDIR}/build/all_errors.json \
+        -x ${WORKDIR}/build/policy_crosscheck.txt
+
+}
+
+addtask report after do_install

meta-ibm/recipes-phosphor/logging/phosphor-logging_%.bbappend

@@ -0,0 +1,23 @@
+PACKAGECONFIG:append:witherspoon-tacoma = " openpower-pels"
+PACKAGECONFIG:append:p10bmc = " openpower-pels"
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/${BPN}:"
+
+SRC_URI:append:p10bmc = " file://ibm,rainier-2u_dev_callouts.json"
+SRC_URI:append:p10bmc = " file://ibm,rainier-4u_dev_callouts.json"
+SRC_URI:append:p10bmc = " file://ibm,everest_dev_callouts.json"
+FILES:${PN}:append:p10bmc = " ${datadir}/phosphor-logging/pels/ibm,rainier-2u_dev_callouts.json"
+FILES:${PN}:append:p10bmc = " ${datadir}/phosphor-logging/pels/ibm,rainier-4u_dev_callouts.json"
+FILES:${PN}:append:p10bmc = " ${datadir}/phosphor-logging/pels/ibm,everest_dev_callouts.json"
+
+#Enable phal feature, if available.
+PACKAGECONFIG:append = " ${@bb.utils.filter('MACHINE_FEATURES', 'phal', d)}"
+PACKAGECONFIG[phal] = "-Dphal=enabled, -Dphal=disabled, pdata libekb pdbg ipl"
+
+do_install:append:p10bmc() {
+    install -d ${D}/${datadir}/phosphor-logging/pels
+    install -m 0644 ${WORKDIR}/ibm,rainier-2u_dev_callouts.json ${D}/${datadir}/phosphor-logging/pels/ibm,rainier-2u_dev_callouts.json
+    install -m 0644 ${WORKDIR}/ibm,rainier-4u_dev_callouts.json ${D}/${datadir}/phosphor-logging/pels/ibm,rainier-4u_dev_callouts.json
+    install -m 0644 ${WORKDIR}/ibm,everest_dev_callouts.json ${D}/${datadir}/phosphor-logging/pels/ibm,everest_dev_callouts.json
+    ln -s ./ibm,rainier-4u_dev_callouts.json ${D}/${datadir}/phosphor-logging/pels/ibm,rainier-1s4u_dev_callouts.json
+}