Initial commit

meta-ibm/recipes-phosphor/dump/debug-trigger/p10bmc/debug-trigger.default

@@ -0,0 +1,2 @@
+DEBUG_TRIGGER_OPTIONS=--sink-actions=dbus
+DEBUG_TRIGGER_SINK=

meta-ibm/recipes-phosphor/dump/debug-trigger_%.bbappend

@@ -0,0 +1,9 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
+
+SRC_URI:append:p10bmc = " file://debug-trigger.default"
+
+do_install:append:p10bmc() {
+        # Install the defaults file
+        mkdir -p ${D}${sysconfdir}/default
+        install -m 0644 -T ${WORKDIR}/debug-trigger.default ${D}${sysconfdir}/default/debug-trigger
+}

meta-ibm/recipes-phosphor/dump/phosphor-debug-collector_%.bbappend

@@ -0,0 +1,38 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/${BPN}:"
+
+PACKAGECONFIG:append:p10bmc = " host-dump-transport-pldm"
+PACKAGECONFIG:append:witherspoon-tacoma = " host-dump-transport-pldm"
+
+PACKAGECONFIG:append:p10bmc = " openpower-dumps-extension"
+PACKAGECONFIG:append:witherspoon-tacoma = " openpower-dumps-extension"
+
+SYSTEMD_SERVICE:${PN}-manager:p10bmc += "clear_hostdumps_poweroff.service"
+SYSTEMD_SERVICE:${PN}-manager:witherspoon-tacoma += "clear_hostdumps_poweroff.service"
+
+EXTRA_OEMESON:append:p10bmc = " -DBMC_DUMP_TOTAL_SIZE=409600"
+EXTRA_OEMESON:append:p10bmc = " -DBMC_DUMP_MAX_SIZE=20480"
+
+install_ibm_plugins() {
+    install ${S}/tools/dreport.d/ibm.d/plugins.d/* ${D}${dreport_plugin_dir}/
+}
+
+#Link in the plugins so dreport run them at the appropriate time
+python link_ibm_plugins() {
+    source = d.getVar('S', True)
+    source_path = os.path.join(source, "tools", "dreport.d", "ibm.d", "plugins.d")
+    op_plugins = os.listdir(source_path)
+    for op_plugin in op_plugins:
+        op_plugin_name = os.path.join(source_path, op_plugin)
+        install_dreport_user_script(op_plugin_name, d)
+}
+
+#Install dump header script from dreport/ibm.d to dreport/include.d
+install_dreport_header() {
+    install -d ${D}${dreport_include_dir}
+    install -m 0755 ${S}/tools/dreport.d/ibm.d/gendumpheader ${D}${dreport_include_dir}/
+}
+
+IBM_INSTALL_POSTFUNCS = "install_ibm_plugins link_ibm_plugins"
+IBM_INSTALL_POSTFUNCS:append:p10bmc = " install_dreport_header"
+
+do_install[postfuncs] += "${IBM_INSTALL_POSTFUNCS}"