Initial commit

meta-delta/meta-ahe50dc/conf/layer.conf

@@ -0,0 +1,10 @@
+# We have a conf and classes directory, add to BBPATH
+BBPATH .= ":${LAYERDIR}"
+
+# We have recipes-* directories, add to BBFILES
+BBFILES += "${LAYERDIR}/recipes-*/*/*.bb \
+            ${LAYERDIR}/recipes-*/*/*.bbappend"
+
+BBFILE_COLLECTIONS += "ahe50dc-layer"
+BBFILE_PATTERN_ahe50dc-layer = "^${LAYERDIR}/"
+LAYERSERIES_COMPAT_ahe50dc-layer = "langdale mickledore"

meta-delta/meta-ahe50dc/conf/machine/ahe50dc.conf

@@ -0,0 +1,36 @@
+KMACHINE = "aspeed"
+KERNEL_DEVICETREE = "${KMACHINE}-bmc-delta-${MACHINE}.dtb"
+
+UBOOT_MACHINE = "evb-ast2400_defconfig"
+UBOOT_DEVICETREE = "ast2400-ahe-50dc"
+
+FLASH_SIZE = "32768"
+
+require conf/machine/include/ast2400.inc
+require conf/machine/include/obmc-bsp-common.inc
+
+PREFERRED_PROVIDER_virtual/obmc-chassis-mgmt = "packagegroup-delta-apps"
+PREFERRED_PROVIDER_virtual/obmc-fan-mgmt = "packagegroup-delta-apps"
+PREFERRED_PROVIDER_virtual/obmc-flash-mgmt = "packagegroup-delta-apps"
+PREFERRED_PROVIDER_virtual/obmc-system-mgmt = "packagegroup-delta-apps"
+
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-aspeed-sdk"
+PREFERRED_PROVIDER_u-boot = "u-boot-aspeed-sdk"
+PREFERRED_PROVIDER_u-boot-fw-utils = "u-boot-fw-utils-aspeed-sdk"
+
+VIRTUAL-RUNTIME_obmc-inventory-manager = "entity-manager"
+VIRTUAL-RUNTIME_obmc-sensors-hwmon = "dbus-sensors"
+
+# features unneeded because ahe50dc doesn't have a host to manage
+IMAGE_FEATURES:remove = " \
+        obmc-chassis-mgmt \
+        obmc-chassis-state-mgmt \
+        obmc-console \
+        obmc-host-ipmi \
+        obmc-host-state-mgmt \
+        obmc-ikvm \
+        obmc-fan-control \
+        obmc-fan-mgmt \
+        "
+
+SERIAL_CONSOLES:ahe50dc = "115200;ttyS2"

meta-delta/meta-ahe50dc/conf/templates/default/bblayers.conf.sample

@@ -0,0 +1,18 @@
+# LAYER_CONF_VERSION is increased each time build/conf/bblayers.conf
+# changes incompatibly
+LCONF_VERSION = "8"
+
+BBPATH = "${TOPDIR}"
+BBFILES ?= ""
+
+BBLAYERS ?= " \
+  ##OEROOT##/meta \
+  ##OEROOT##/meta-poky \
+  ##OEROOT##/meta-openembedded/meta-oe \
+  ##OEROOT##/meta-openembedded/meta-networking \
+  ##OEROOT##/meta-openembedded/meta-python \
+  ##OEROOT##/meta-phosphor \
+  ##OEROOT##/meta-aspeed \
+  ##OEROOT##/meta-delta \
+  ##OEROOT##/meta-delta/meta-ahe50dc \
+  "

meta-delta/meta-ahe50dc/conf/templates/default/local.conf.sample

@@ -0,0 +1,17 @@
+MACHINE ??= "ahe50dc"
+DISTRO ?= "openbmc-phosphor"
+PACKAGE_CLASSES ?= "package_ipk"
+SANITY_TESTED_DISTROS:append ?= " *"
+EXTRA_IMAGE_FEATURES = "debug-tweaks"
+USER_CLASSES ?= "buildstats"
+PATCHRESOLVE = "noop"
+BB_DISKMON_DIRS = "\
+    STOPTASKS,${TMPDIR},1G,100K \
+    STOPTASKS,${DL_DIR},1G,100K \
+    STOPTASKS,${SSTATE_DIR},1G,100K \
+    STOPTASKS,/tmp,100M,100K \
+    HALT,${TMPDIR},100M,1K \
+    HALT,${DL_DIR},100M,1K \
+    HALT,${SSTATE_DIR},100M,1K \
+    HALT,/tmp,10M,1K"
+CONF_VERSION = "2"

meta-delta/meta-ahe50dc/recipes-bsp/u-boot/files/ahe50dc.cfg

@@ -0,0 +1,2 @@
+CONFIG_PHY_BROADCOM=y
+CONFIG_BOOTARGS="console=ttyS2,115200n8 root=/dev/ram rw"

meta-delta/meta-ahe50dc/recipes-bsp/u-boot/u-boot-aspeed-sdk_%.bbappend

@@ -0,0 +1 @@
+require u-boot-common-aspeed-sdk.inc

meta-delta/meta-ahe50dc/recipes-bsp/u-boot/u-boot-common-aspeed-sdk.inc

@@ -0,0 +1,5 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+SRC_URI:append = " \
+    file://ahe50dc.cfg \
+    "

meta-delta/meta-ahe50dc/recipes-bsp/u-boot/u-boot-fw-utils-aspeed-sdk_%.bbappend

@@ -0,0 +1 @@
+require u-boot-common-aspeed-sdk.inc

meta-delta/meta-ahe50dc/recipes-delta/packagegroups/packagegroup-delta-apps.bb

@@ -0,0 +1,40 @@
+SUMMARY = "OpenBMC for Delta Power - Applications"
+PR = "r1"
+
+inherit packagegroup
+
+PROVIDES = "${PACKAGES}"
+PACKAGES = " \
+        ${PN}-chassis \
+        ${PN}-fans \
+        ${PN}-flash \
+        ${PN}-system \
+        "
+
+PROVIDES += "virtual/obmc-chassis-mgmt"
+PROVIDES += "virtual/obmc-fan-mgmt"
+PROVIDES += "virtual/obmc-flash-mgmt"
+PROVIDES += "virtual/obmc-system-mgmt"
+
+RPROVIDES:${PN}-chassis += "virtual-obmc-chassis-mgmt"
+RPROVIDES:${PN}-fans += "virtual-obmc-fan-mgmt"
+RPROVIDES:${PN}-flash += "virtual-obmc-flash-mgmt"
+RPROVIDES:${PN}-system += "virtual-obmc-system-mgmt"
+
+SUMMARY:${PN}-chassis = "Delta Power Chassis"
+RDEPENDS:${PN}-chassis = " \
+        "
+
+SUMMARY:${PN}-fans = "Delta Power Fans"
+RDEPENDS:${PN}-fans = " \
+        "
+
+SUMMARY:${PN}-flash = "Delta Power Flash"
+RDEPENDS:${PN}-flash = " \
+        phosphor-ipmi-flash \
+        "
+
+SUMMARY:${PN}-system = "Delta Power System"
+RDEPENDS:${PN}-system = " \
+        bmcweb \
+        "

meta-delta/meta-ahe50dc/recipes-kernel/linux/linux-aspeed/ahe50dc.cfg

@@ -0,0 +1,15 @@
+CONFIG_SENSORS_DELTA_AHE50DC_FAN=y
+
+# efuse driver components
+CONFIG_REGULATOR=y
+CONFIG_REGULATOR_USERSPACE_CONSUMER=y
+CONFIG_SENSORS_LM25066_REGULATOR=y
+
+# not needed for hostless BMC
+CONFIG_SERIAL_8250_ASPEED_VUART=n
+CONFIG_IPMI_KCS_BMC=n
+CONFIG_ASPEED_KCS_IPMI_BMC=n
+CONFIG_ASPEED_LPC_CTRL=n
+CONFIG_ASPEED_LPC_SNOOP=n
+CONFIG_IPMI_KCS_BMC_CDEV_IPMI=n
+CONFIG_ASPEED_BT_IPMI_BMC=n

meta-delta/meta-ahe50dc/recipes-kernel/linux/linux-aspeed_git.bbappend

@@ -0,0 +1,5 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/${PN}:"
+
+SRC_URI += " \
+    file://ahe50dc.cfg \
+    "