Initial commit

meta-aspeed/recipes-aspeed/images/aspeed-image-initramfs.bb

@@ -0,0 +1,3 @@
+IMAGE_FSTYPES = "${INITRAMFS_FSTYPES}"
+
+require recipes-core/images/core-image-minimal.bb

meta-aspeed/recipes-aspeed/images/aspeed-image-norootfs.bb

@@ -0,0 +1,40 @@
+SUMMARY = "Two partition MTD image with u-boot and kernel"
+HOMEPAGE = "https://github.com/openbmc/meta-aspeed"
+LICENSE = "MIT"
+
+inherit deploy
+
+UBOOT_SUFFIX ?= "bin"
+ASPEED_IMAGE_KERNEL_OFFSET_KB ?= "512"
+ASPEED_IMAGE_SIZE_KB ?= "32768"
+ASPEED_IMAGE_KERNEL_IMAGE ?= "fitImage-${INITRAMFS_IMAGE}-${MACHINE}-${MACHINE}"
+ASPEED_IMAGE_NAME ?= "aspeed-norootfs-${MACHINE}.bin"
+
+do_compile() {
+    dd if=/dev/zero bs=1k count=${ASPEED_IMAGE_SIZE_KB} | \
+        tr '\000' '\377' > ${B}/aspeed-norootfs.bin
+    dd if=${DEPLOY_DIR_IMAGE}/u-boot.${UBOOT_SUFFIX} of=${B}/aspeed-norootfs.bin \
+        conv=notrunc
+    dd if=${DEPLOY_DIR_IMAGE}/${ASPEED_IMAGE_KERNEL_IMAGE} \
+        of=${B}/aspeed-norootfs.bin conv=notrunc \
+        seek=${ASPEED_IMAGE_KERNEL_OFFSET_KB} bs=1k
+}
+
+do_deploy() {
+    install -m644 -D ${B}/aspeed-norootfs.bin ${DEPLOYDIR}/${ASPEED_IMAGE_NAME}
+}
+
+do_compile[depends] = "virtual/kernel:do_deploy u-boot:do_deploy"
+do_fetch[noexec] = "1"
+do_unpack[noexec] = "1"
+do_patch[noexec] = "1"
+do_configure[noexec] = "1"
+do_install[noexec] = "1"
+deltask do_populate_sysroot
+do_package[noexec] = "1"
+deltask do_package_qa
+do_packagedata[noexec] = "1"
+deltask do_package_write_ipk
+deltask do_package_write_deb
+deltask do_package_write_rpm
+addtask deploy before do_build after do_compile

meta-aspeed/recipes-aspeed/python/socsec.inc

@@ -0,0 +1,26 @@
+SUMMARY = "Secure-boot utilities for ASPEED BMC SoCs"
+HOMEPAGE = "https://github.com/AspeedTech-BMC/socsec/"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d50b901333b4eedfee074ebcd6a6d611"
+
+BRANCH ?= "master"
+SRC_URI = "git://github.com/AspeedTech-BMC/socsec.git;protocol=https;branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+inherit python3native setuptools3
+
+DEPENDS += "${PYTHON_PN}-bitarray-native"
+DEPENDS += "${PYTHON_PN}-ecdsa-native"
+DEPENDS += "${PYTHON_PN}-pycryptodome-native"
+
+RDEPENDS:${PN} += "${PYTHON_PN}-bitarray"
+RDEPENDS:${PN} += "${PYTHON_PN}-core"
+RDEPENDS:${PN} += "${PYTHON_PN}-jsonschema"
+RDEPENDS:${PN} += "${PYTHON_PN}-jstyleson"
+RDEPENDS:${PN} += "${PYTHON_PN}-pycryptodome"
+RDEPENDS:${PN} += "${PYTHON_PN}-ecdsa"
+
+BBCLASSEXTEND = "native nativesdk"
+

meta-aspeed/recipes-aspeed/python/socsec_2.0.0.bb

@@ -0,0 +1,3 @@
+include socsec.inc
+
+SRCREV = "32fb3f1b2d0955233122d0ffd53cb7833d97eb87"