Initial commit

meta-aspeed/conf/layer.conf

@@ -0,0 +1,10 @@
+# We have a conf and classes directory, add to BBPATH
+BBPATH .= ":${LAYERDIR}"
+
+BBFILES += "${LAYERDIR}/recipes-*/*/*.bb \
+            ${LAYERDIR}/recipes-*/*/*.bbappend"
+
+BBFILE_COLLECTIONS += "aspeed-layer"
+BBFILE_PATTERN_aspeed-layer := "^${LAYERDIR}/"
+LAYERVERSION_aspeed-layer = "1"
+LAYERSERIES_COMPAT_aspeed-layer = "langdale mickledore"

meta-aspeed/conf/machine/distro/include/uboot-distrovars.inc

@@ -0,0 +1 @@
+OVERRIDES .= ":uboot-flash-${FLASH_SIZE}"

meta-aspeed/conf/machine/evb-ast2500.conf

@@ -0,0 +1,11 @@
+KERNEL_DEVICETREE = "aspeed-ast2500-evb.dtb"
+
+UBOOT_MACHINE = "evb-ast2500_defconfig"
+UBOOT_DEVICETREE = "ast2500-evb"
+
+require conf/machine/include/ast2500.inc
+require conf/machine/include/obmc-evb-common.inc
+
+SERIAL_CONSOLES = "115200;ttyS4"
+
+FLASH_SIZE = "32768"

meta-aspeed/conf/machine/evb-ast2600.conf

@@ -0,0 +1,22 @@
+KERNEL_DEVICETREE = "aspeed-ast2600-evb.dtb"
+
+UBOOT_MACHINE = "ast2600_openbmc_spl_defconfig"
+UBOOT_DEVICETREE = "ast2600-evb"
+SPL_BINARY = "spl/u-boot-spl.bin"
+# Disable hardware root of trust by default.
+# If users want to enable secure boot,
+# please do the following steps.
+# 1. Set SOCSEC_SIGN_ENABLE to “1”.
+# 2. Provide platform OTP config.
+# There was an example in p10bmc.
+# If users enable socsec signing but do not provide OTP config,
+# u-boot will be built failed.
+SOCSEC_SIGN_ENABLE = "0"
+
+require conf/machine/include/ast2600.inc
+require conf/machine/include/obmc-evb-common.inc
+
+SERIAL_CONSOLES = "115200;ttyS4"
+
+# AST2600 EVB has 64MB SPI flash
+FLASH_SIZE = "65536"

meta-aspeed/conf/machine/include/aspeed.inc

@@ -0,0 +1,57 @@
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-aspeed"
+
+PREFERRED_PROVIDER_virtual/bootloader ?= "u-boot-aspeed-sdk"
+PREFERRED_PROVIDER_u-boot ?= "u-boot-aspeed-sdk"
+PREFERRED_PROVIDER_u-boot-fw-utils ?= "u-boot-fw-utils-aspeed-sdk"
+
+# Build a FIT image and stuff core-image-minimal in it by default.
+KERNEL_IMAGETYPE ?= "fitImage"
+KERNEL_CLASSES ?= "kernel-fitimage"
+INITRAMFS_IMAGE ?= "aspeed-image-initramfs"
+INITRAMFS_FSTYPES ?= "cpio.xz"
+
+WKS_FILE ?= "emmc-aspeed.wks.in"
+WKS_FILE_DEPENDS ?= " \
+    phosphor-hostfw-image \
+    virtual/bootloader \
+    virtual/kernel \
+"
+WKS_HOSTFW_SIZE ?= "5G"
+IMAGE_BOOT_FILES ?= "fitImage-${INITRAMFS_IMAGE}-${MACHINE}-${MACHINE};fitImage"
+
+MACHINE_EXTRA_RRECOMMENDS += "udev-aspeed-vuart udev-aspeed-mtd-partitions"
+MACHINE_FEATURES += "hw-rng"
+
+MACHINEOVERRIDES =. "aspeed:"
+
+SERIAL_CONSOLES ?= "115200;ttyS4"
+
+DEFAULTTUNE:aspeed-g5 ?= "arm1176jzs"
+DEFAULTTUNE:aspeed-g6 ?= "armv7ahf-vfpv4d16"
+
+UBOOT_ENTRYPOINT:aspeed-g4 ?= "0x40001000"
+UBOOT_ENTRYPOINT:aspeed-g5 ?= "0x80001000"
+UBOOT_ENTRYPOINT:aspeed-g6 ?= "0x80001000"
+UBOOT_LOADADDRESS:aspeed-g4 ?= "0x40001000"
+UBOOT_LOADADDRESS:aspeed-g5 ?= "0x80001000"
+UBOOT_LOADADDRESS:aspeed-g6 ?= "0x80001000"
+
+# runqemu support
+EXTRA_IMAGEDEPENDS += "qemu-helper-native"
+IMAGE_CLASSES += "qemuboot"
+QB_SYSTEM_NAME = "qemu-system-arm"
+QB_ROOTFS_OPT = "-drive file=@ROOTFS@,if=mtd,format=raw"
+QB_DEFAULT_FSTYPE = "static.mtd"
+# Disable virtio-pci device
+QB_RNG = ""
+QB_NETWORK_DEVICE = "-net nic"
+# Boot from drive
+QB_DEFAULT_KERNEL = "none"
+# runqemu overrides default memory size
+QB_MEM = "-m 512"
+
+QB_MACHINE:aspeed-g4 = "-machine palmetto-bmc"
+QB_MACHINE:aspeed-g5 = "-machine ast2500-evb"
+QB_MACHINE:aspeed-g6 = "-machine ast2600-evb"
+QB_MEM:aspeed-g5 = "-m 1G"
+QB_MEM:aspeed-g6 = "-m 1G"

meta-aspeed/conf/machine/include/ast2400.inc

@@ -0,0 +1,4 @@
+SOC_FAMILY = "aspeed-g4"
+include conf/machine/include/soc-family.inc
+require conf/machine/include/aspeed.inc
+require conf/machine/include/arm/armv5/tune-arm926ejs.inc

meta-aspeed/conf/machine/include/ast2500.inc

@@ -0,0 +1,4 @@
+SOC_FAMILY = "aspeed-g5"
+include conf/machine/include/soc-family.inc
+require conf/machine/include/aspeed.inc
+require conf/machine/include/arm/armv6/tune-arm1176jz-s.inc

meta-aspeed/conf/machine/include/ast2600.inc

@@ -0,0 +1,9 @@
+SOC_FAMILY = "aspeed-g6"
+
+# Enable SPL signing by default
+SOCSEC_SIGN_ENABLE ?= "1"
+SOCSEC_SIGN_SOC ?= "2600"
+
+include conf/machine/include/soc-family.inc
+require conf/machine/include/aspeed.inc
+include conf/machine/include/arm/arch-armv7a.inc

meta-aspeed/conf/templates/default/bblayers.conf.sample

@@ -0,0 +1,7 @@
+BBPATH = "${TOPDIR}"
+BBFILES ?= ""
+
+BBLAYERS ?= " \
+  ##OEROOT##/meta \
+  ##OEROOT##/meta-aspeed \
+  "

meta-aspeed/conf/templates/default/local.conf.sample

@@ -0,0 +1,5 @@
+#MACHINE ?= "evb-ast2500"
+MACHINE ??= "evb-ast2600"
+
+# Allow logging in if the user does not set the root password.
+EXTRA_IMAGE_FEATURES ?= "debug-tweaks"